From 8a4b4bd155b083c6766374adfb3e7647e27fc4e8 Mon Sep 17 00:00:00 2001
From: Phillip Webb <pwebb@vmware.com>
Date: Sun, 4 Aug 2013 14:20:26 -0700
Subject: [PATCH] Add spring.bat start script for Windows

---
 spring-boot-cli/src/main/scripts/spring.bat | 76 +++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 spring-boot-cli/src/main/scripts/spring.bat

diff --git a/spring-boot-cli/src/main/scripts/spring.bat b/spring-boot-cli/src/main/scripts/spring.bat
new file mode 100644
index 00000000000..bff7df2db09
--- /dev/null
+++ b/spring-boot-cli/src/main/scripts/spring.bat
@@ -0,0 +1,76 @@
+@if "%DEBUG%" == "" @echo off
+
+@rem Set local scope for the variables with windows NT shell
+if "%OS%"=="Windows_NT" setlocal
+
+:setSpringHome
+@rem Setup SPRING_HOME if not already defined
+if defined SPRING_HOME goto setJavaHome
+set DIRNAME=%~dp0
+if "%DIRNAME%" == "" set DIRNAME=.
+set SPRING_HOME=%DIRNAME%\..
+
+:setJavaHome
+@rem Find java.exe
+if defined JAVA_HOME goto findJavaFromJavaHome
+set JAVA_EXE=java.exe
+%JAVA_EXE% -version >NUL 2>&1
+if "%ERRORLEVEL%" == "0" goto runSpring
+echo.
+echo ERROR: JAVA_HOME is not set and no 'java' command could be found in your PATH.
+echo.
+echo Please set the JAVA_HOME variable in your environment to match the
+echo location of your Java installation.
+goto fail
+
+:findJavaFromJavaHome
+set JAVA_HOME=%JAVA_HOME:"=%
+set JAVA_EXE=%JAVA_HOME%/bin/java.exe
+if exist "%JAVA_EXE%" goto runSpring
+echo.
+echo ERROR: JAVA_HOME is set to an invalid directory: %JAVA_HOME%
+echo.
+echo Please set the JAVA_HOME variable in your environment to match the
+echo location of your Java installation.
+goto fail
+
+:runSpring
+@rem Get command-line arguments, handling Windows variants
+
+if not "%OS%" == "Windows_NT" goto win9xME_args
+if "%@eval[2+2]" == "4" goto 4NT_args
+
+:win9xME_args
+@rem Slurp the command line arguments.
+set CMD_LINE_ARGS=
+set _SKIP=2
+
+:win9xME_args_slurp
+if "x%~1" == "x" goto execute
+
+set CMD_LINE_ARGS=%*
+goto execute
+
+:4NT_args
+@rem Get arguments from the 4NT Shell from JP Software
+set CMD_LINE_ARGS=%$
+
+:execute
+@rem Setup the command line
+
+set CLASSPATH=%SPRING_HOME%\lib\*
+"%JAVA_EXE%" %JAVA_OPTS% -cp "%CLASSPATH%" org.springframework.boot.cli.SpringCli %CMD_LINE_ARGS%
+
+:end
+@rem End local scope for the variables with windows NT shell
+if "%ERRORLEVEL%"=="0" goto mainEnd
+
+:fail
+rem Set variable SPRING_EXIT_CONSOLE if you need the _script_ return code instead of
+rem the _cmd.exe /c_ return code!
+if  not "" == "%SPRING_EXIT_CONSOLE%" exit 1
+exit /b 1
+
+:mainEnd
+if "%OS%"=="Windows_NT" endlocal
+